Membuat Lookup Data Program Aplikasi VB6

Salah satu komponen yang penting dalam aplikasi yang kita susun adalah bisa menampilkan data-data sebelumnya yang telah kita input, sebagai bagian dari pencarian data yang akan ditampilkan atau diedit. Dalam istilah pemrograman adalah searching atau lookup data. Pada kesempatan ini saya akan menjelaskan sekaligus memberikan contoh program aplikasi yang menggunakan komponen Lookup Data tersebut, berikut Source Code yang bisa anda download.

Pada contoh program aplikasi tersebut berhubungan dengan source code diartikel sebelumnya yaitu Program Koneksi Database SQL Server dengan SQLOLEDB. Berikut penjelasan tentang contoh program Lookup Data dengan VB6 dan database SQL Server.

Mengambil Data (Recordset)

Pertama yang harus anda lakukan untuk untuk menyiapkan data yang akan anda tampilkan dalam form lookup adalah dengan membuat class yang berfungsi untuk menampilkan recordset dari tabel yang anda maksud, seperti contoh kode program dibawah ini:


Public Function Lookup(oConnection As Object) As Object
    Dim oCmd As New ADODB.Command
    Dim oResult As ADODB.Recordset
    Dim SQL As String
    
    SQL = "SELECT KodeBarang, NamaBarang, Satuan, StokAkhir, HargaJual " + _
          "FROM MasterBarang " + _
          "ORDER BY NamaBarang"
          
    oCmd.ActiveConnection = oConnection
    oCmd.CommandType = adCmdText
    oCmd.CommandText = SQL
    
    oConnection.CursorLocation = adUseClient
    Set oResult = oCmd.Execute
    Set oResult.ActiveConnection = Nothing
    Set Lookup = oResult
    oConnection.CursorLocation = adUseServer

    Set oResult = Nothing
    Set oCmd = Nothing
End Function

Mendefinisikan Variabel Public untuk Pencarian (Lookup Data)

Selanjutnya anda definisikan sebuah variabel yang bersifat Public untuk menyimpan data yang dipilih dari Lookup Data, yang ditulis dalam Module. Misalkan dalam contoh tersebut kita menggunakan nama variabel DataSeleksi, sehingga dalam kode program module kita tulis seperti contoh dibawah ini:


Option Explicit

Public DataSeleksi As String

Mengaktifkan Form Lookup

Untuk mengaktifkan form lookup data, anda buat sebuah Command Button, misalkan dengan nama cmdLookupData maka dalam event Click dari button tersebut kita buat kode program seperti contoh dibawah ini:


Private Sub cmdLookupData_Click()
    Set frmLookup.ConnectionObject = oConnection
    frmLookup.Show vbModal
    
    'Jika ada data yang dipilih
    If Trim(DataSeleksi) <> "" Then
       txtKodeBarang.Text = DataSeleksi
       Call txtKodeBarang_LostFocus
    End If
End Sub

Pada contoh event Click diatas difungsikan untuk menampilkan fmrLookupData dengan sifat vbModal, dan hasil pencarian akan disimpan dalam variabel DataSeleksi. Jika data seleksi tidak kosong berarti ada data yang kita pilih dan selanjutnya ditampilkan dan digunakan dalam event txtKodeBarang_LostFocus.

Pada form LookupData secara prinsip dibuat kode program program yang berfungsi membaca data (recordset) dari tabel yang dimaksud dalam komponen Listview, kemudian memberikan pilihan untuk memilih atau membatalkan, dengan contoh kode program lengkap seperti contoh dibawah ini:


Option Explicit

Public ConnectionObject As Object

Private Sub cmdBatal_Click()
    DataSeleksi = ""
    Unload Me
End Sub

Private Sub cmdPilih_Click()
    If lsvLookup.ListItems.Count > 0 Then
       DataSeleksi = Trim(lsvLookup.SelectedItem.Text)
       Unload Me
    End If
End Sub

Private Sub Form_Load()
    BacaDataBarang
End Sub

Private Sub BacaDataBarang()
    Dim oMasterBarang As New MasterBarang
    Dim oResult As New ADODB.Recordset
    Dim oItemData As ListItem
    
    lsvLookup.ListItems.Clear
    Set oResult = oMasterBarang.Lookup(ConnectionObject.Server)
    While Not oResult.EOF
          Set oItemData = lsvLookup.ListItems.Add
          
          oItemData.Text = Trim(oResult!KodeBarang)
          oItemData.SubItems(1) = Trim(oResult!NamaBarang)
          oItemData.SubItems(2) = Trim(oResult!Satuan)
          oItemData.SubItems(3) = Format(oResult!StokAkhir, "###,##0.00")
          oItemData.SubItems(4) = Format(oResult!HargaJual, "###,##0")
          
          oResult.MoveNext
    Wend
End Sub

Untuk lebih jelasnya anda bisa download contoh program tersebut Membuat Lookup Data Program Aplikasi VB6 disini. Semoga artikel ini bermanfaat.

Download Source Code VB6

Kodiing

Membuat Lookup Data Program Aplikasi VB6

Mengambil Data (Recordset)

Mendefinisikan Variabel Public untuk Pencarian (Lookup Data)

Mengaktifkan Form Lookup